Files-In-Use Extension for Inno Setup

Posted on the March 17th, 2007 under Raz-Soft News, [ En ] by Raz

First of all I would like to give a big thanks to Jordan Russell for the best freeware installer for Windows programs: Inno Setup. If you need to deploy your applications this is the best free tool you will find, trust me. If you don’t want to write script by hand you can always use ISTool to edit these scripts faster in a visual and easy environment.

Files-In-Use functionality is among the countless services that Windows Installer exposes for setup authors to leverage for their application install/maintenance. This functionality lets setup authors display the processes that hold on to files that would be updated by this install. The user would want to shut those processes before continuing with the install to ensure that the install wouldnâ€™t require a reboot.

Now you can do the same thing with Inno Setup avoiding unnecessary reboots when installing your application exe files / plugin / shell extension / ocx etc with My Files In Use Extension for Inno Setup
Features:

small size (it will add less than 20KB to your setup. )
multi-language support (you can add or modify the language file)

100% FREE AWARD

multiple file search (a semicolon list with exe/dll/ocx names and path can be used)
wildcard file match ( * = matches any characters, zero or more times ; ? = matches any character, one time )
exact folder match (detect if your file is in use only from a specified folder )
applications exe names will be listed not just their description
both 32 and 64 bit applications detection (Vista & XP x64 )
user friendly: applications are displayed along with their icon
possibility to end the detected process forcedly (right click on process for more options)
easy to use and 100% free

How do I get it to work with Inno?
1. Download latest File In Use Extension for Inno (IssProc.dll and Inno script demo included)
2. Add the extension (IssProc.dll) in your [Files] section script :

1
2
3
4
5
6
7
8
9

[Files]

;------ add Files In Use Extension

Source: IssProc.dll; DestDir: {tmp}; Flags: dontcopy

;------ add Files In Use Extension extra language file (you don t need to add this file if you are using english only)

Source: IssProcLanguage.ini; DestDir: {tmp}; Flags: dontcopy

;------ Copy IssProc.dll in your app folder if you want to use it on unistall

Source: IssProc.dll; DestDir: {app}

Source: IssProcLanguage.ini; DestDir: {app}

;------

3. Add below code in your [Code] section script (you can modify it as you like):

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79

[Code]

// IssFindModule called on install

function IssFindModule(hWnd: Integer; Modulename: PChar; Language: PChar; Silent: Boolean; CanIgnore: Boolean ): Integer;

external 'IssFindModule@files:IssProc.dll stdcall setuponly';

// IssFindModule called on uninstall

function IssFindModuleU(hWnd: Integer; Modulename: PChar; Language: PChar; Silent: Boolean; CanIgnore: Boolean ): Integer;

external 'IssFindModule@{app}\IssProc.dll stdcall uninstallonly';

//********************************************************************************************************************************************

// IssFindModule function returns: 0 if no module found; 1 if cancel pressed; 2 if ignore pressed; -1 if an error occured

//

//  hWnd        = main wizard window handle.

//

//  Modulename  = module name(s) to check. You can use a full path to a DLL/EXE/OCX or wildcard file name/path. Separate multiple modules with semicolon.

//                 Example1 : Modulename='*mymodule.dll';     -  will search in any path for mymodule.dll

//                 Example2 : Modulename=ExpandConstant('{app}\mymodule.dll');     -  will search for mymodule.dll only in {app} folder (the application directory)

//                 Example3 : Modulename=ExpandConstant('{app}\mymodule.dll;*myApp.exe');   - just like Example2 + search for myApp.exe regardless of his path.

//

//  Language    = files in use language dialog. Set this value to empty '' and default english will be used

//                ( see and include IssProcLanguage.ini if you need custom text or other language)

//

//  Silent      = silent mode : set this var to true if you don't want to display the files in use dialog.

//                When Silent is true IssFindModule will return 1 if it founds the Modulename or 0 if nothing found

//

//  CanIgnore   = set this var to false to Disable the Ignore button forcing the user to close those applications before continuing

//                set this var to true to Enable the Ignore button allowing the user to continue without closing those applications

//******************************************************************************************************************************************

function NextButtonClick(CurPage: Integer): Boolean;

var

  hWnd: Integer;

  sModuleName: String;

  nCode: Integer;  {IssFindModule returns: 0 if no module found; 1 if cancel pressed; 2 if ignore pressed; -1 if an error occured }

begin

  Result := true;

 if CurPage = wpReady then

   begin

      Result := false;

      ExtractTemporaryFile('IssProcLanguage.ini');                          { extract extra language file - you don't need to add this line if you are using english only }

      hWnd := StrToInt(ExpandConstant('{wizardhwnd}'));                     { get main wizard handle }

      sModuleName :=ExpandConstant('{app}\Myprog.exe');                     { searched modules. Tip: separate multiple modules with semicolon Ex: '*mymodule.dll;*mymodule2.dll;*mymodule3.dll'}

     nCode:=IssFindModule(hWnd,sModuleName,'en',false,true);                { search for module and display files-in-use window if found  }

     //sModuleName:=IntToStr(nCode);

    // MsgBox ( sModuleName, mbConfirmation, MB_YESNO or MB_DEFBUTTON2);

     if nCode=1 then  begin                                                 { cancel pressed or files-in-use window closed }

          PostMessage (WizardForm.Handle, $0010, 0, 0);                     { quit setup, $0010=WM_CLOSE }

     end else if (nCode=0) or (nCode=2) then begin                          { no module found or ignored pressed}

          Result := true;                                                   { continue setup  }

     end;

  end;

end;

function InitializeUninstall(): Boolean;

var

  sModuleName: String;

  nCode: Integer;  {IssFindModule returns: 0 if no module found; 1 if cancel pressed; 2 if ignore pressed; -1 if an error occured }

begin

    Result := false;

      sModuleName := ExpandConstant('*Myprog.exe;');    { searched module. Tip: separate multiple modules with semicolon Ex: '*mymodule.dll;*mymodule2.dll;*myapp.exe'}

     nCode:=IssFindModuleU(0,sModuleName,'enu',false,false); { search for module and display files-in-use window if found  }

     if (nCode=0) or (nCode=2) then begin                    { no module found or ignored pressed}

          Result := true;                                    { continue setup  }

     end;

    // Unload the extension, otherwise it will not be deleted by the uninstaller

    UnloadDLL(ExpandConstant('{app}\IssProc.dll'));

end;

4. Set sModuleName from the above code with your own modules names (separate multiple modules with semicolon)
5. Compile and test your setup. Before Inno will begin install operation The File In Use Extension will check if your modules (DLL’s/exe’s/ocx’s names) are in use and it will popup with a window asking the user to close those applications. The user can choose to Ignore this and continue with setup rebooting at the end, or he can close those applications and click on Retry.

Notes: Starting with Inno Setup v5.3.0 script the ‘PChar’ type has been renamed to ‘PAnsiChar’. Just Replace all occurrences of ‘PChar’ type to ‘PAnsiChar’ in the above example if you are using InnoSetup v5.3 or newer.

Version History

Download

IssProc v1.0.2 (Files In Use Extension for Inno Setup) [1552 downloads]

Donate Download Build Notes Report

Who’s Using IssProc?

ZGuideTV
My Kids Browser

( If you are you using IssProc and want to be listed here please let me know! )

42 Responses to 'Files-In-Use Extension for Inno Setup'

Subscribe to comments with RSS

April 7, 2007 at 11:22 am
George

Reply

Hi,
Is there a way to translate the popup window asking the user to close those applications? I need a translation for a germany setup file.
Thanks
April 7, 2007 at 12:29 pm
Raz

Reply

Hi George,
The popup window is in English and there is no multi-language support for now, but multi-lang support is scheduled to be added in the next build.
Thanks
April 15, 2007 at 10:33 pm
Raz

Reply

Multi-language support added in IssProc.dll v1.0.1
July 7, 2007 at 11:06 am
Crulex

Reply

My installation fails under Vista Enterprise x64, as well as the sample setup I’ve compiled from your sample.
I’m getting the following error immediately after launching setup:
—————————
Runtime Error (at -1:

Cannot Import dll:C:\TEMP\is-SL00G.tmp\IssProc.dll.
—————————
I tried changing the script to delay load your dll but it stll fails during the installation.
On Win98/2000/WinXP anything goes fine.
I wonder it might be smth with manifests, etc.
July 7, 2007 at 11:32 am
Raz

Reply

Hi Crulex,
It looks like Inno Setup cannot Import the DLL in Vista Enterprise x64. I guess the only thing that causes the failure is the extension packer (used to reduce the size). The only thing I can do is to send you the unpacked version of the extension, you can download it from here
Please let me know if the unpacked version works on your installlation.
July 12, 2007 at 4:23 am
Mark

Reply

I am using your unpacked version on Vista 64 Business edition as the other one wont work. If possible could you please add detection of 64 bit programs?
July 12, 2007 at 12:41 pm
Crulex

Reply

Hi Raz,
Thanks for the feedback, I’ve just needed to resolve this issue today.
The unpacked version works very well on my Vista x64 installation.
I’ve found that the packed version installs correctly if I turn off DEP on my Vista installation by running the following command from the command prompt with administrative privileges:

bcdedit.exe /set {current} nx AlwaysOff

It seems that a lot of the execiutable packers are incompatible with DEP
September 25, 2007 at 9:55 am
Raz

Reply

Hi all,
IssProc v1.0.2 is out: no more packer and DEP problems (i hope), support for both 32 & 64 apps, fully tested on XP and Vista x64 and more user friendly. Let me know your thoughts
Thank you
November 13, 2007 at 1:45 pm
Neo

Reply

Hi,

During install in english we can see on the main form ‘Setup - My Program’ and in french ‘Installation - My program’ … great !

But during uninstall in english we can see on the main form ‘Setup’ and in french ’setup’

It should be great during uninstall to see in english ‘Setup - My Program’ and in french ‘DÃ©sinstallation - My Program’ like in inno setup !

I do not really understand how to add a second language in the code (french and english). Could you give me an example please ?

I’ve translated the IssProcLanguage.ini file in french. If you want this one email me please

Thanks for all

Neo
November 13, 2007 at 2:27 pm
Raz

Reply

Hi Neo,
For now caption on install/uninstall can not be set from language file but I will add that on my “to do list”.

For your translation: in the file IssProcLanguage.ini file create a section called [fr] (used on install ) and [fru] (unsinstall) and add your translated variables just like those in english, something like this (you can copy the below code and translate):

;***** [French language] Install ****
[fr]
; *** Labels ***
TopBoldLabel=Files in use
TopSubLabel=Some files that needed to be updated are currently in use.
MoreInfoLabel=The following applications are using files that need to be updated by this setup. Close these applications and then click Retry to continue the installation or Cancel to exit it.
;*** Buttons ***
CancelButton=&Cancel
IgnoreButton=&Ignore
RetryButton=&Retry

;**[French language] Uninstall ***********
[fru]
; *** Labels ***
TopBoldLabel=Files in use
TopSubLabel=Some files that needed to be removed are currently in use.
MoreInfoLabel=The following applications are using files that need to be removed by this setup. Close these applications and then click Retry to continue uninstalling or Cancel to exit it.
;*** Buttons ***
CancelButton=&Cancel
IgnoreButton=&Ignore
RetryButton=&Retry

After you add (and translate) the above sections use “fr” and “fru” for language param of IssProc function like this:

nCode:=IssFindModule(hWnd,sModuleName,’fr’,false,true);

and on uninstall like this:

nCode:=IssFindModule(hWnd,sModuleName,’fru’,false,true);

Please send you translation file at: razvar .at. gmail .dot. com and I will reply you with the working/modified french one.

Thanks
November 13, 2007 at 3:42 pm
Neo

Reply

Hi,

Yes working great with : nCode:=IssFindModule(hWnd,sModuleName,’fr’,false,true);

and : nCode:=IssFindModule(hWnd,sModuleName,’fru’,false,true);

But in fact I use innosetup in multi language in my case the users select english or french during the first screen !

And right now I just can use IssProc in english or french but not the both.

I hope you understand what I mean !

Neo
November 15, 2007 at 7:55 pm
Raz

Reply

Hi Neo,

You must modify your script and put additional checks: If the user has selected the english language then use IssProg with ‘en’ value on the language param. If it selects french then use IssProc with ‘fr’ and so on…You must have some experience with inno script (delphi/pascal) to make that work.

I can help you out with that too, but right now time is not on my side. Send me your script (attach the language file as well) and I shall modify it for you one more time

Raz
May 17, 2008 at 1:37 am
Daniel

Reply

Hi,

Is it possible to get the name and icon of the file-in-use from the app’s main window, instead of getting it from the FileVersion info? This is what Task Manager does for the "Applications" tab, as it is generally more useful/correct than just the FileVersion info.

The exact problem I’m having is this: when the file-in-use is a Java app, IssProc will display something like "Java (TM) 2 Platform Standard Edition binary (javaw.exe)" with the ugly default icon. Of course, most users have no idea what that is!

I think that getting the icon and name from the FileVersion info is a good backup strategy for processes that don’t have any windows.

Thanks for a nice utility!

Daniel
November 17, 2008 at 4:03 am
Mitchell

Reply

I’m trying to use your Inno code with a shell extension and am not having any luck at all. It never reports that the DLL is in use so it never prompts the user to do anything. It seems so straightforward that I can’t imagine what I’m doing wrong. Does it just not work for shell extensions?
- May 11, 2009 at 8:38 am
  Raz
  
  Reply
  
  It works just fine for shell extensions, this is the main reason why I made this extension. Just make sure you write the searched module with wildcard to match any folder: ‘*mymodule.dll’
November 21, 2008 at 3:31 pm
Alexander

Reply

Hi,

Is there a way to change the order of the Retry/Ignore/Cancel buttons? Its easy for a user who quickly hits ‘Next>’ to skip the popup dialog, because Ignore comes roughly at the same spot as ‘Next>’. I want to make Retry the middle button.
January 20, 2009 at 8:18 am
Syam S

Reply

Hi,

Is there any way to disable the prompting the user for ending the running process?I need to kill the process from the setup without the intervention of user.

Please help….

Thanks and regards,
Syam S
- May 11, 2009 at 8:40 am
  Raz
  
  Reply
  
  There is now way to do this ,you can hide the window but you can not kill the process automatically. I can add this feature in a new build…
  - November 30, 2009 at 6:13 am
    Xeek
    
    Reply
    
    I made another extension that adds that functionality. It force kills an exe/module name you give, then I run raz’s extension after mine in case it doesn’t work out. Let me know if you want it, xeek@x3software.com
February 13, 2009 at 5:36 am
Vaz

Reply

Translation brazilian portuguese for IssProcLanguage.ini:

TopBoldLabel=Arquivos em uso
TopSubLabel=Alguns arquivos de precisam ser removidos estÃ£o em uso
MoreInfoLabel=As aplicaÃ§Ãµes listadas estÃ£o usando arquivos que necesitam ser removidos por este desinstalador.
Encerreas-as e clique em Tentar Novamente para continuar a desinstalaÃ§Ã£o
;*** Buttons ***
CancelButton=&Cancelar
IgnoreButton=&Ignorar
RetryButton=&Tentar Novamente
- May 11, 2009 at 8:40 am
  Raz
  
  Reply
  
  Thank you for your translation.
April 21, 2009 at 11:16 pm
sg

Reply

Hi Raz,

This one is an excellent one. One more thing I wanted to add is can we not give one more parameter so that we can kill the exe silentely insted of the user to end the process. That might be usefull when the user knows that only one exe is being used and he has to just kill it.
Hope you understand that iam saying. I had writen a small dll and was trying to achieve that feature but i am encountering some issues
“Cannot Import dll:”

Hope to see your reply soon

Regards,
-SG
- May 11, 2009 at 8:43 am
  Raz
  
  Reply
  
  Thank you. It will be usefull, but right now I’m to busy with other projects. If you really want this feature I can make a private build for you for a small donation
May 10, 2009 at 12:35 am
Clark L

Reply

Hello,

I just came across this extension and it does exactly what I was looking for. I’m having an issue with ‘Retry’. When I click it, even though I have exited the process I was checking for, it still shows in the list and I am unable to continue with setup. If I exit setup and re-run, I can continue on fine. Is it possibly something I need to put in to my setup script that controls this behavior? I’m running this on Server 2008 64-Bit and using the latest Inno Setup version.

Thank you,
Clark L
- May 11, 2009 at 8:34 am
  Raz
  
  Reply
  
  Hi Clark,
  
  This is a 64bit issue, I got a beta fix here if you want to give it a try. Please let me know if it works on you and I will release it as soon as posible. I don’t have suffcient resources for full 64bit tests, sorry.
  
  Thanks.
June 29, 2009 at 8:15 pm
mlodyno

Reply

Hello. IssProc is great but I have a small problem. I use IssProcLanguage.ini to show instructions in Polish. It is ok in some WindowsXP and Vista but sometimes in win98 or some XPs instructions are shown in English. I guest that it is problem with including .ini and finally is shown oryginaly english instuction probably from issProc.dll.
It is very important to display all informations in Polish… Can I ask for help? May I ask for translated issProc.dll file? Or any other ways to solve my problem? Thanks!!!
- September 1, 2009 at 9:24 am
  Raz
  
  Reply
  
  Hi and thanks for the feedback,
  
  I can make you a custom IssProc build, just drop me a mail with your texts to discuss further.
July 21, 2009 at 1:49 am
Brandon

Reply

http://raz-soft.com/IssProcv1.0.3.453.rar

this fixed the issues with the 64 bit windows, but it didn’t uninstall IssProc.dll and yes I do have this in my code:

1
UnloadDLL(ExpandConstant('{app}\IssProc.dll'));
- September 1, 2009 at 2:32 am
  Clark L
  
  Reply
  
  I also was finally able to try http://raz-soft.com/IssProcv1.0.3.453.rar and it fixes the ‘retry’ issue with 64-bit Windows, but I am also having an issue where the UnloadDLL call doesn’t seem to be working and the DLL can’t be deleted by the installer without a reboot.
September 1, 2009 at 9:26 am
Raz

Reply

Hi, sorry for the delayed response.

@Brandon, Clark L
Is this happening only on 64bit Windows? Because I can’t replicate. Thanks
September 5, 2009 at 5:23 pm
Brandon

Reply

The file is now being removed I guess it was an issue with the file.

Also new problem, It is not detecting program on running on installation.
- September 7, 2009 at 4:54 pm
  Raz
  
  Reply
  
  What do you mean by “It is not detecting program on running on installation.” are you sure you’re searching for the right one, with wildcard?

September 7, 2009 at 4:22 pm
Brandon

Need some help, I would like to use this with another feature but they both use the same function function NextButtonClick(CurPage: Integer): Boolean;

So I did this:
function NextButtonClick(CurPage: Integer): Boolean;
begin
if CurPage = wpReady then
begin
Result := CheckAppRun() and CheckNET();
end;
end;

and created function CheckAppRun(): Boolean;
with the code from the NextButtonClick minus the if CurPage = wpReady then. But now I when I run the setup program I’m unable to get next click to work. Any help on why this is please let me know?

September 7, 2009 at 5:09 pm
Raz

Try to simplify it, make it more readable to find the problem, do something like this:

1
2
3
4
5
6
7
8
9
10

{....blah blah init code...}

begin

  Result := true; {default return value } 

sModuleName:=ExpandConstant('{app}\Myprog.exe'); 

nCode:=IssFindModule(hWnd,sModuleName,'en',false,true);

if nCode=1 then  begin

       PostMessage (WizardForm.Handle, $0010,0, 0); {canceled}

end else if (nCode=0) or (nCode=2) then begin

 Result:=CheckNET();                               

end;

November 8, 2009 at 12:32 am
David

Reply

Just wanted to say thanks.
The extension works great for me.
November 10, 2009 at 4:55 am
Miguel Vivanco

Reply

Intenta de esta manera (Try this way):
Var
obj: Variant
va: MyVariableType;
Begin
//Starting
ExtractTemporaryFile(’MyDll.dll’);
RegisterServer(False, ExpandConstant(’{tmp}\MyDll.dll’), False);
obj := CreateOleObject(’MyDll.MyClass’);
//Using
va := obj.MyFunction();
//Finishing
UnregisterServer(False, ExpandConstant(’{tmp}\MyDll.dll’), False);
DeleteFile(’{tmp}\MyDll.dll’);
End;

Suerte (good luck)
November 18, 2009 at 5:33 am
Kite

Reply

I have issue with not deleting IssProc.dll after uninstalling application on Win7 x64
December 7, 2009 at 4:29 pm
zakyn

Reply

Hello, I haqve a problem with compilation.

Parsing [Files] section, line 332
Reading version info: ..\InnoS
etup5_unicode\IssProc.dll
Parsing [Files] section, line 334
Reading version info: ..\InnoS
etup5_unicode\IssProcLanguage.ini
Parsing [Files] section, line 336
Parsing [Files] section, line 337
Compiling [Code] section
Error on line 506 in .\InstallationScripts\GrpOffice2.iss:
Column 51:
Unknown type ‘PChar’
Compile aborted.

What is wrong please?

Thanks

Zakyn
- December 8, 2009 at 5:00 pm
  Raz
  
  Reply
  
  Starting with Inno Setup v5.3.0 script the ‘PChar’ type has been renamed to ‘PAnsiChar’. Just Replace all occurrences of ‘PChar’ type to ‘PAnsiChar’.
  - January 14, 2010 at 4:02 pm
    zeroG
    
    Reply
    
    With version 5.3.6 you will get an “Unknown type ‘PAnsiChar’” error if you do so.
    
    Other than that, thank you for this add-on!!
December 22, 2009 at 9:45 pm
TStarGermany

Reply

superb add-on .. thanks !!!
September 11, 2009 at 5:50 pm
Clark L

Reply

I should say, though, that the new DLL did fix the retry problem on 64-bit Windows for me, so I appreciate you fixing that!